D2R Server tutorial

Author: Vadim Eisenberg

1. Download and uncompress D2R Server
   • For Windows:
     1. http://sourceforge.net/projects/d2rq-map/files/D2R%20Server/v0.7%20%28alpha%29/d2r-server-0.7.zip/download
     2. Unzip the d2r-server-0.7 directory
   • For other OS:
     1. http://sourceforge.net/projects/d2rq-map/files/D2R%20Server/v0.7%20%28alpha%29/d2r-server-0.7.tar.gz/download

     2. $ tar xfz d2r-server-0.7.tar.gz

2. Download a dump of an example database (with some entries from the ISWC 2002 conference): http://d2rq.org/example/iswc-mysql.sql
3. Create a database "iswc" in MySQL
4. Feed the downloaded iswc-mysql.sql into mysql by running (you should specify the full path of the downladed iswc-mysql.sql if you run mysql in another directory):

   $ mysql -u [username] -p[password] < iswc-mysql.sql

5. Check that the database was created OK. In MySql run, for example:

   show tables;

   and

   select FirstName, LastName, email from persons;

   
6. Download the example mapping file mapping-iswc.ttl
7. Change the username in the downloaded mapping file to be your mysql username and add a password of your mysql (if the password is required for your mysql)

   

8. Run d2r-server in the directory you uncompressed it in the step 1 (you should specify the full path of the mapping-iswc.ttl if you run mysql in another directory):

   d2r-server -p 8080 mapping-iswc.ttl

   
9. Open the following URL with your web browser: http://localhost:8080/snorql/

   

10. Run an example SPARQL query. Write the query into the text of the SPARQL section and push the "Go!" button. You will see the results of the query in the SPARQL results section. The following query returns the names and the email addresses of all the people in the database. You can see that the results match the SQL query select FirstName, LastName, email from persons; that you ran in mysql

    SELECT DISTINCT ?name ?email WHERE {
      ?person rdf:type foaf:Person.
      ?person foaf:name ?name ;
              foaf:mbox ?email
    }
    

    
11. Examples of additional SPARQL queries
    • Select people and topics of their interest:

      SELECT DISTINCT ?personName ?topicName  WHERE {
        ?person rdf:type foaf:Person.
        ?person foaf:name ?personName.
        ?person iswc:research_interests ?topic.
        ?topic rdfs:label ?topicName .
      } 
      

    • Select persons whose research interests include Semantic Web:

      SELECT DISTINCT ?personName ?topicName  WHERE {
        ?person rdf:type foaf:Person.
        ?person foaf:name ?personName.
        ?person iswc:research_interests ?topic.
        ?topic rdfs:label ?topicName .
        FILTER (?topicName = "Semantic Web")
      } 
      

    • Select all organizations where the people interested in Semantic Web work:

      SELECT DISTINCT ?organizationName ?personName  WHERE {
        ?person rdf:type foaf:Person.
        ?person foaf:name ?personName.
        ?person iswc:research_interests ?topic.
        ?topic rdfs:label ?topicName .
        FILTER (?topicName = "Semantic Web").
        ?person iswc:has_affiliation ?organization .
        ?organization rdfs:label ?organizationName
      } 
      

    • Select people who wrote papers on the topic "Semantic Web"

      SELECT DISTINCT ?personName ?paperTitle  WHERE {
        ?paper dc:creator ?person .
        ?person foaf:name ?personName.
        ?paper dc:title ?paperTitle  .
        ?paper skos:subject ?topic.
        ?topic rdfs:label ?topicName .
        FILTER (?topicName = "Semantic Web")
      }
      

    • Select people who wrote papers on topic that is not of their interest:

      SELECT DISTINCT ?personName ?paperTitle  ?paperTopicName WHERE {
        ?paper dc:creator ?person .
        ?person foaf:name ?personName.
        ?paper dc:title ?paperTitle  .
        ?paper skos:subject ?paperTopic.
        ?paperTopic rdfs:label ?paperTopicName .
        OPTIONAL { ?person iswc:research_interests ?personTopic . 
                    FILTER (?personTopic = ?paperTopic) }
        FILTER ( !BOUND(?personTopic) )
      } 
      

    • Select papers and their authors and organizations:

      SELECT DISTINCT ?paperTitle ?authorName ?organizationName WHERE {
        ?paper dc:creator ?author .
        ?author foaf:name ?authorName.
        ?paper dc:title ?paperTitle  .
        ?author iswc:has_affiliation ?organization .
        ?organization rdfs:label ?organizationName
      }
      

    • Select papers that were written by authors from different organizations:

      SELECT DISTINCT ?paperTitle ?authorName ?organizationName WHERE {
        ?paper dc:creator ?author .
        ?author foaf:name ?authorName.
        ?paper dc:title ?paperTitle  .
        ?author iswc:has_affiliation ?organization .
        ?organization rdfs:label ?organizationName
        OPTIONAL { ?paper dc:creator ?anotherAuthor .
                   ?anotherAuthor iswc:has_affiliation ?anotherOrganization .
                   FILTER(?anotherAuthor != ?author && 
                          ?anotherOrganization != ?organization) }
        FILTER ( BOUND(?anotherAuthor))
      }
      

12. And what if you want to update the data in the mapped database ? You can use SPARQL/Update and D2RQ/Update and D2R/Update Server prototype extensions. See the tutorial about D2RQ/Update and D2R/Update Server.